ElderlyAssistant/app/build.gradle

apply plugin: 'com.android.application'

def appName() {
    return "TTStdElderlyAssistant"
}

def releaseTime() {
    return new Date().format("yyyyMMdd_HHmmss", TimeZone.getDefault())
}

android {
    namespace "com.ttstd.elderlyassistant"

    compileSdkVersion 29
    buildToolsVersion "36.0.0"

    defaultConfig {
        applicationId "com.ttstd.elderlyassistant"
        //There are no CERT files because If the mini sdk version is 23+, the AGP will ignore the V1 scheme signature.
        minSdkVersion 23
        targetSdkVersion 29
        versionCode 1
        versionName "1.0"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"

        ndk {
            //根据需要 自行选择添加的对应cpu类型的.so库。
            abiFilters 'armeabi', 'armeabi-v7a', 'arm64-v8a', 'x86', 'x86_64'
            // 还可以添加 'armeabi','armeabi-v7a', 'x86', 'x86_64', 'mips', 'mips64'
        }

        lintOptions {
            checkReleaseBuilds false
            // Or, if you prefer, you can continue to check for errors in release builds,
            // but continue the build even when errors are found:
            abortOnError false
        }

    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    buildFeatures {
        dataBinding true
        buildConfig true
        aidl true
    }

    signingConfigs {
        keypub {
            storeFile     file(rootProject.ext.signingConfigs.keypub.storeFile)
            storePassword rootProject.ext.signingConfigs.keypub.storePassword
            keyAlias      rootProject.ext.signingConfigs.keypub.keyAlias
            keyPassword   rootProject.ext.signingConfigs.keypub.keyPassword
        }
    }

    buildTypes {
        debug {
            versionNameSuffix "_debug"
            debuggable true
            minifyEnabled false
            signingConfig signingConfigs.keypub
        }

        release {
            minifyEnabled false
            //前一部分代表系统默认的android程序的混淆文件，该文件已经包含了基本的混淆声明，后一个文件是自己的定义混淆文件
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.keypub
        }
    }

    applicationVariants.all { variant ->
        variant.outputs.each { output ->
            def buildType = variant.buildType.name

            if (buildType.contains("debug")) {
                output.outputFileName = "${appName()}_V${defaultConfig.versionName}_${releaseTime()}.apk"
            } else {
                output.outputFileName = "${appName()}_${variant.versionCode}_V${variant.versionName}_${releaseTime()}_${buildType}.apk"
            }
        }
    }

}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    implementation 'androidx.appcompat:appcompat:1.3.1'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.4'

    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'

    //glide
    implementation 'com.github.bumptech.glide:glide:4.13.1'
    annotationProcessor 'com.github.bumptech.glide:compiler:4.13.1'
    //RxJava
    implementation 'io.reactivex.rxjava3:rxjava:3.0.0'
    implementation 'io.reactivex.rxjava3:rxandroid:3.0.0'
    //
    implementation 'com.squareup.okhttp3:okhttp:4.7.0'
    //log打印
    implementation 'com.squareup.okhttp3:logging-interceptor:4.7.0'
    implementation 'com.squareup.retrofit2:retrofit:2.9.0'
    implementation 'com.squareup.retrofit2:converter-gson:2.9.0'
//    implementation 'com.squareup.retrofit2:adapter-rxjava2:2.4.0'
    implementation "com.squareup.retrofit2:adapter-rxjava3:2.9.0"
    //Gson
    implementation 'com.google.code.gson:gson:2.9.0'
    implementation 'com.google.zxing:core:3.5.0'
    //生命周期管理
    implementation 'com.trello.rxlifecycle4:rxlifecycle:4.0.2'
    implementation 'com.trello.rxlifecycle4:rxlifecycle-android:4.0.2'
    implementation 'com.trello.rxlifecycle4:rxlifecycle-components:4.0.2'
    implementation 'com.trello.rxlifecycle4:rxlifecycle-components-preference:4.0.2'
    implementation 'com.trello.rxlifecycle4:rxlifecycle-android-lifecycle:4.0.2'

    implementation 'com.jakewharton.rxbinding4:rxbinding:4.0.0'
    /*https://github.com/JeremyLiao/LiveEventBus*/
    implementation 'com.jeremyliao:live-event-bus-x:1.7.3'

    //MMKV
    implementation 'com.tencent:mmkv-static:2.4.0'
    //bugly
    implementation 'com.tencent.bugly:crashreport:4.1.9.2'
    implementation 'com.iqiyi.xcrash:xcrash-android-lib:3.0.0'

    //工具类
    implementation 'com.blankj:utilcodex:1.31.0'
    //autosize会改变第三方view的大小
    //https://github.com/JessYanCoding/AndroidAutoSize
    implementation 'me.jessyan:autosize:1.2.1'
    // 吐司框架：https://github.com/getActivity/Toaster
    implementation 'com.github.getActivity:Toaster:12.6'
    //图片裁切
    implementation 'com.github.yalantis:ucrop:2.2.10'
}